samedi 28 août 2010

[POWERSHELL] provider en alias

pour mettre le provider variable: comme alias on passera par une fonction comme ceci

  PS> function global:variable: {"test"}
  PS> set-alias variable: global:variable:
  PS> variable:
test 

Tri numérique

Pour trier des données on a la commande SORT.EXE mais malheureusement elle n'effectue que le trie alphabétique:
Salut,


Pour trier des données on a la commande SORT.EXE mais malheureusement elle n'effectue que le trie alphabétique:

c:\> type fichier1.txt

1 marcoc
2 libye
3 palestine
4 france

c:\> sort /r /+2 fichier1.txt /o trier.txt
c:\> type trier.txt

3 palestine
1 maroc
2 libye
4 france


un autre exemple:

c:\> type fichier2.txt

5
3
6
1

c:\> sort fichier2.txt

1
3
5
6


jusqu'ici tout marche à la perfection, voyons maintenant cette exemple:
c:\> type fichier3.txt

65
1
26894
1125
369

c:\> sort fichier3.txt

1
1125
26894
369
65

comme vous voyez la commande SORT.EXE ne connait pas le trie numérique.

pour contourner ce problème, on peux utiliser la commande externe "gnu sort" avec l'option "-n"
c:\> gnusort -n fichier3.txt

1
65
369
1125
26894

une autre solution est de faire un script émulant la commande "gnusort -n".

Donc l'une des solution possible est de fixer la longueur des chaine de caractères pour qu'il aillent la même longueur, pour se faire on va ajouter des zero "0" à gauche de chaque chaine:
00000001
00001125
00026894
00000369
00000065

ensuite on va les passer à la commande SORT.EXE

c:\> Sort fichier4.txt
00000001
00000065
00000369
00001125
00026894

le trie est effectuer avec succès il nous ne reste plus qu'a enlever les zeros "0" de plus.
1
65
369
1125
26894

et voilà voyons notre script de quoi aura l'air:
@Echo oFF
Setlocal EnableExtensions

Set liste=1 1125 26894 369 65 396

For %%i in (%liste%) Do >>~@ Call :S %%i
For /F "Tokens=*" %%c in ('Sort ~@') do Call:P set "c=%%c"
del ~@
pause
Endlocal & goto :EOF

:S
Set "tz=00000000%1"
Echo:%tz:~-8%
goto :EOF

:P
%*
:z
if (%c:~0,1%)==(0) set "c=%c:~1%" & goto:z
echo=%c% 
goto:EOF


comme vous voyez c'est le bordel !! On essayera alors une autre solution,...que dites-vous de
comparer les nombres, nombre par nombre en décalant chaque chiffre de gauche à droite, le plus grand nombre sera décalé à droite et le plus petit à gauche ? un SORT à bulle...quoi..
@Echo oFF

Call :Sort 1256 280 3 10 2 98 259 563 8
pause
goto :EOF


:Sort
Setlocal EnableDelayedExpansion
Set/A n=1,s=0,c=s,r=s
for %%: In (%*) do (
    Set /a c+=1
    Set "nm.!c!=%%:")
:LP.1
if %s% EQU %c% Set/A n+=1,s=0
    Set/A s+=1
    Call :SPL %n% %s%
If %n% LEQ %c% goto :LP.1
:LP.2
    Echo:!nm.%c%!
    Set/A c-=1
If %c% GTR 0 goto :LP.2 
Endlocal & goto :EOF
:SPL
 If !nm.%1! GTR !nm.%2! (
   Set "t=!nm.%2!"&Set "nm.%2=!nm.%1!"
   Set "nm.%1=!t!"
 ) 
goto :EOF

c'est plus simple..non.. :)

dimanche 18 juillet 2010

fonctions utiles

voici quelques fonctions utiles


1/ extraire d'une chaîne de caractères uniquement les lettres /ou les nombres:
@Echo oFF
Setlocal EnableExtensions

Call :Xtract 65446gjkngd5343dflgd
set substr 
Endlocal & goto :eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:Xtract  %1=chaîne de caractères  %2=paramètre optionnel [$str]
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Setlocal enableExtensions
If [%2]==[$str] Set "v1=-v" & set "v2=^"
Set is=%~1
For /F "Tokens=2 Delims=:" %%# In ('
  "%Comspec% /u /cEcho:%is%|More|FindStr -o .|FindStr %v1% ".*:[%v2%0-9]"
 ') do Call Set substr=%%substr%%%%#
Endlocal & Set "substr=%substr%" & goto :eof


voici quelques exemples:

Call :xtract "45ds8f9558fr5r585f854447r"  
echo %substr%

c:\> tst.bat

45895585585854447


Call :xtract "45ds8f9558fr5r585f854447r"  $str
echo %substr%

c:\> tst.bat

dsffrrfr 


2/ afficher les propriétés avancées d'un fichier:

:AdvancedProp
Setlocal EnableExtensions
If Not Exist "%~f1" Exit /B 2
For %%x In (
    "0:$Nom","1:$Taille","2:$Type","3:$Date.Modif"
    "4:$Date.Create","5:$Date.Access","6:$Attribut"
    "7:$Etat","8:$Proprietaire","9:$Auteur"
    "10:$Titre","11:$objet","12:$Categorie"
    "14:$Commentaire","15:$Copyright","16:$Artist"
    "17:$Titre.Album","18:$Annee","19:$Numero.Piste"
    "20:$Genre","21:$Duree","23:$Protege"
    "26:$Dimension","34:$Chaines","35:$Entreprise"
    "36:$Description","37:$Version.Fichier"
    "38:$Nom.Produit","39:$Version.Produit"
    "40:$Mots.Clefs" 
) Do For /F "Tokens=1* Delims=:" %%s In (%%x) Do (
   >$ Call :$Prop "%~1" %%s %%t 
     set "%%t="
     for /f "tokens=* delims=" %%a in ('
           "cscript -nologo -e:vbs $ & del $"
    ') Do %%a
     if defined %%t Set %%t
)
Endlocal & goto :EOF
:$Prop
echo Set o=createObject("shell.application").^
     namespace("%~dp1")
echo wsh.echo "set %3="^&o.^
     getdetailsof(o.parsename("%~nx1"),%2)
Exit /B 0


Call :AdvancedProp "%windir%\explorer.exe"


3/ Lire un fichier à l'envers:

:fileRev
for /f "tokens=1* delims=][" %%s in ('

find /n /v "" ^< %1') do (
    Set "tab[%%s]=%%t"
    if not defined tab[%%s] set tab[%%s]=µµµ
    Set nline=%%s
)
for /l %%i in (%nline% -1 1) Do (
  for /f "tokens=1* delims=µ=" %%_ in ('

set tab[%%i]

') do echo=%%_
)
goto:eof


Call :fileRev "mon fichier de test.txt" 


4/ Convertir une chaîne de caractères en majuscule:

:ucase
for /f "tokens=1* delims=µ" %%a in ('
  "tree \µµµ%1|find ":\""
  ') do set "ucase=%%b"
goto:eof

 

Call :ucase "tunisia"


5/ Inverse une chaîne de caractère:

:reverse
for /f "tokens=1* delims=:" %%a in ('
    "%comspec% /u /c echo:%~1|more|findstr /o ."
 ') do set "reverse=%%b!reverse!"
goto:eof

 

 Call :reverse "vive palestine" 


6/ a* Convertir un nombre décimal en hexa

:tohexa
Setlocal enableextensions
set hx=0x0
Set exp=%comspec% /cexit/b %1^&set;^|find "^=ExitCode^="
for /f "tokens=1* delims=0=" %%a in ('
      "%exp%" % expression evalue %
') do Set hx=0x%%b
Endlocal & Set "hex=%hx%" & goto :eof


 set hex=98
 set hex
 Call :tohexa %hex% && Set hex   


6/ b* Convertir un nombre décimal en hexa:

:tohexa
for /f "tokens=1,3" %%i in ('^(
 reg add hkcu\console /v hexa /t reg_dword /d %1 /f ^&
 reg query hkcu\console /v hexa  ^&
 reg delete hkcu\console /v hexa /f
 ^)^|find "REG_DWORD"') do Set %%i=%%j
goto:eof

 

set hexa=685

set hexa & Call :tohexa %hexa% & set hexa



7/ Compter le nombre de répétition d'une lettre:

:CountChar
for /f %%: in ('
  "%comspec% /u /c echo:%~1|more|sort"
 ') do Set /A "$[%%:]+=1"
goto:eof


Call :CountChar "tunisia and africa"
Set $[


8/ Supprimer les espaces de plus en debut/fin d'un string:

@echo off 
(set Ch=    ceci    est un simple test   )
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
set path=%path%;D:\Program Files\GnuWin32\bin
set e="s_^\s*__;s_\s*$__;s_^_del %%0\&set %%1=&_w ~.Cmd"
echo [%Ch%]
echo\%Ch%|1>&0 sed %e%
2>Nul=(call ~.Cmd ch)
echo [%Ch%]&goto:EOF :::::GnuSED Version 4.2::::::::::::::::

samedi 19 juin 2010

Compter le nombre de caractères

VBS-LIKE

@echo off
call:LCount %*
echo %length%
goto:EOF
:LCount
echo/wsh.echo "set length="^&Len("%*")>..vbs
cscript/nologo ..vbs>..bat
for %%. in (call del) do %%. ..bat ..vbs
goto:EOF 


VBS-LIKE

@echo off
echo\Input=Inputbox("String:","Input")>..vbs
echo\wsh.echo "set length="^&Len(Input)>>..vbs
cscript/nologo ..vbs>..bat
for %%. in (call del) do %%. ..bat ..vbs
echo\%length%
pause 


VBS-LIKE

@echo off
set str=%*
echo>len.vbs c=len(wsh.arguments.item(0)):wsh.echo c
for /f  %%i in ('cscript/nologo len.vbs "%str%"') do set len=%%i
echo LENGTH=%len%
del len.vbs
goto:EOF 


NATIVE

Set Str=hello
for /f "tokens=1* delims=[]" %%a in ('
  "%comspec% /u /c echo:%Str%|more|find /n /v """
 ') do set /a "length=%%a-4"
goto:eof

Remplacement de chaine de caractères

voici quelques méthodes, parmis d'autres, pour remplacer une chaîne de caractères par une autre, avec un fichier batch

1-Utilisation de l'utilitaire Edlin
@echo off
REM batfile infile "search" "rep"
REM EXEMPLE: batfile test.txt a A
REM ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
set/p="1r%~2"-
copy /a -+nul>nul
set/p="%~3"--
copy /b -+-- --->nul
echo.>>---
echo>>--- w
echo>>--- 900a
echo>>--- e
type --- |>nul edlin /b %1
del - -- ---
goto:EOF



2- VBS-LIKE
@echo off
set file=a.txt
set oldstr=u
set newstr=#MAJ#

For %%A in (
  "do until Wsh.stdin.atendofstream    " 
  "  o="%oldstr%" :  n="%newstr%"      "
  "  ch=replace(wsh.stdin.readline,o,n)"
  "  Wsh.echo ch                       "
  "loop"
) do >>__.vbs echo\%%~A 
type %file% |>' cscript /nologo __.vbs && move ' %file%
del __.vbs
exit /b






mercredi 16 juin 2010

naviguer dans la base de registre

salut,

voici une astuce pour naviguer dans la base de registre assez facilement:
l'astuce consiste à copier la clef du registre dans la mémoire pour ensuite l'exploiter grâce à un utilitaire NIRCMD.EXE


raccourcis pour naviguer dans la base de registre from WALID on Vimeo.

dimanche 13 juin 2010

.Bat VS .Cmd


Les Fichiers de commandes MS-DOS connus sous le nom .BAT diffèrent des Scripts de commandes Windows NT connus sous le nom .CMD
Cette différence, n'est si grande, elle se situe fondamentalement sur la portabilité des .Bat au contraires des fichiers .CMD et l'intérprétation des erreurs retournées par quelques commandes internes à l'intérpréteur.
   
  @echo off 
  set test=CMD
  Call :sub 6
  set test=BAT
  If errorlevel 6 (echo BAT) else (echo CMD)
  goto:eof

  :sub
  exit /b %1
  goto :eof